Linden Scripting Language

default 
{ 
	state_entry() 
	{ 
		llSay(0, "Hello, Avatar!"); 
	} 

	touch_start(integer total_number) 
	{ 
		llSay(0, "Touched."); 
	} 
}

// Global variables must be declared above any functions created and above the first "default" state.
// Many LSL scripts are open source, and can be edited by their owners.
// Often scripts have settings variables with instructions for editing written as comments around them.

 // This list of sound file names would be populated by the owner.
list songs = ["Box_Of_Rain", 9.2, "Servant", 9.8];

integer volume = 10; // All variables (global or local) must have their type declared on creation.
integer lis_count;
integer playing;
integer busy; // Values need not be applied to variable at creation.
integer part;
integer lis;
integer sl;
float delay;
list cancel = ["CANCEL"];
list playlist;
list waiting;
list song;
string vol_str = "Volume";
string song_str = "Songs";
string song_name;

// Variable names (as well as function names and state names) must begin with a letter (upper or lower case) or any number of underscores.
// Variable names cannot begin with a numeral, but they may contain numerals as any other character.

// User created functions can be created by simply naming the function.
// Functions that return a value, must have the value type declared as the type for the function.
// Arguments passed to the function must have their types declared. the type of data passed to the function must match the argument type.
list StrideOfList(list src, integer stride, integer start, integer end) {
	list l = [];
	integer ll = llGetListLength(src);
	if(start < 0)start += ll;
	if(end < 0)end += ll;
	if(end < start) return llList2List(src, start, start);
	while(start <= end) {
		l += llList2List(src, start, start);
		start += stride;
	}
	return l;
}
list Volumes(integer vol) {
	integer v = 0;
	list l = [];
	do {
		if(v != vol) // Single instruction conditional blocks need not be wrapped in braces.
		l += [((string)v)];
	}
	while((++v) <= 10);
	return l;
}
PageOne(key k, integer c) {
	llDialog(k, "\nAdjust the volume or select a song to play?", [vol_str, song_str] + cancel, c);
}
PlaySong(string n) {
	song = [];
	integer c = -1;
	string name = "";
	do { // Functions may be nested and used inline where values are returned (the values need not be stored to a variable for use).
		if(llSubStringIndex((name = llGetInventoryName(INVENTORY_SOUND, (++c))), n) != -1)
		song += [name];
	}
	while(name);
	delay = llList2Float(songs, (llListFindList(songs, [n]) + 1));
	if((sl = llGetListLength(song))) {
		llPreloadSound(llList2String(song, (part = 0)));
		if(sl > 1)
		llPreloadSound(llList2String(song, 1));
		playing = FALSE;
		llSetTimerEvent(0.01);
	}
}
integer Chan() {
	return llRound((llFrand(-5000000.0) + -500000.0));
}
float ScaleVol(integer v) {
	return (v * 0.1);
}
Listen(integer c, key a) {
	lis = llListen(c, "", a, "");
}
RemoveListen(integer b) {
	llListenRemove(lis);
	lis_count = 0;
	if(b)
	busy = FALSE;
	lis = 0;
}
SetListenTimer(integer p) {
	if(p)
	while(((++lis_count) * llRound(delay)) < 30);
	else {
		lis_count = 1;
		llSetTimerEvent(30.0);
	}
}
integer CheckWaitingRoom(integer c) {
	if(waiting) {
		key a = llList2Key(waiting, 0);
		if(!c) {
			RemoveListen(0);
			Listen((c = Chan()), a);
			SetListenTimer(playing);
		}
		PageOne(a, c);
		waiting = llDeleteSubList(waiting, 0, 0);
		return 1;
	}
	return 0;
}

// All scripts must have a default state.
// However many other states a script may have, the default state must be uppermost in the script (below global vars and functions).
default {
	// Event names are written in all lower case letters. Some contain underscores.
	on_rez(integer param) {
		// If an event is passed any values as it is triggered, those values will be of specific types.
		// Writers can choose the name for the variable, but not the type.
		// Even if the data contained in the variables passed to the event are not used, the event must contain reference to that data.
		llStopSound();
		llResetScript();
	}
	changed(integer change) {
		if(change & CHANGED_INVENTORY) // Bitwise comparison
		llResetScript();
	}
	touch_start(integer nd) {
 		while(nd) {
			key agent = llDetectedKey(--nd);
			if(!busy) {
 				busy = TRUE;
				integer channel = Chan();
				SetListenTimer(playing);
				Listen(channel, agent);
				PageOne(agent, channel);
			} else {
				list a = [agent];
				if(llListFindList(waiting, a) == -1)
				waiting += a;
			}
		}
	}
	listen(integer chan, string name, key id, string msg) {
		if(msg != llList2String(cancel, 0)) {
			SetListenTimer(playing);
			if(msg == vol_str) {
				llDialog(id, "\nChange the volume?\nThe current volume is set at \"" + ((string)volume) +
					"\"", cancel + Volumes(volume), chan);
				return;
			}
			if(msg == song_str) {
				string current = "";
				if(playlist) {
					current = "\n\nThe songs currently queued are\n\"" + llList2String(playlist, 0) +
						"\" (currently playing)";
					if(llGetListLength(playlist) > 1)
					current += "\n\"" + llDumpList2String(llList2List(playlist, 1, -1), "\"\n\"") + "\"";
				}
				llDialog(id, llGetSubString(("\nSelect a song to play?" + current), 0, 500), cancel +
					StrideOfList(songs, 2, 0, -1), chan);
				return;
			}
			if(llListFindList(Volumes(volume), [msg]) != -1) {
				llAdjustSoundVolume(ScaleVol((volume = ((integer)msg))));
 				PageOne(id, chan);
				return;
			}
			if(llGetListLength((playlist += [msg])) == 1)
			PlaySong((song_name = msg));
		}
		if(CheckWaitingRoom(chan))
		return;
		RemoveListen(1);
	}
	timer() {
		if(playlist) {
			if(!playing) {
				llSetTimerEvent(delay);
				playing = TRUE;
			}
			llPlaySound(llList2String(song, part), ScaleVol(volume));
			if((++part) == sl) {
				if(llGetListLength(playlist) > 1) {
					song_name = llList2String((playlist = llDeleteSubList(playlist, 0, 0)), 0);
					llSleep(delay);
					PlaySong(song_name);
				} else {
					llSetTimerEvent(0.0);
					song_name = "";
					playing = FALSE;
					playlist = [];
				}
			}
			else if(part == (sl - 1))
			llPreloadSound(llList2String(song, 0));
			else
			llPreloadSound(llList2String(song, (part + 1)));
		}
		if(lis && (!(--lis_count))) {
			if(!(CheckWaitingRoom(0)))
			RemoveListen(1);
		}
	}
}